83de583fb1
This PR fixes the warning from entering the nix development shell:
```
evaluation warning: 'hostPlatform' has been renamed to/replaced by 'stdenv.hostPlatform'
```
Decided to go with `zed-editor = mkZed pkgs;` instead of `zed-editor =
packages.${pkgs.stdenv.hostPlatform.system}.default;`, because it is
simpler and with my understanding it is logically equivalent (i.e. we
are getting `packages.<system>.default` which we can see in the
definition of packages is equal to `mkZed pkgs;`).
Release Notes:
- N/A
67 lines
1.7 KiB
Nix
67 lines
1.7 KiB
Nix
{
|
|
description = "High-performance, multiplayer code editor from the creators of Atom and Tree-sitter";
|
|
|
|
inputs = {
|
|
nixpkgs.url = "https://channels.nixos.org/nixpkgs-unstable/nixexprs.tar.xz";
|
|
rust-overlay = {
|
|
url = "github:oxalica/rust-overlay";
|
|
inputs.nixpkgs.follows = "nixpkgs";
|
|
};
|
|
crane.url = "github:ipetkov/crane";
|
|
flake-compat.url = "github:edolstra/flake-compat";
|
|
};
|
|
|
|
outputs =
|
|
{
|
|
nixpkgs,
|
|
rust-overlay,
|
|
crane,
|
|
...
|
|
}:
|
|
let
|
|
systems = [
|
|
"x86_64-linux"
|
|
"x86_64-darwin"
|
|
"aarch64-linux"
|
|
"aarch64-darwin"
|
|
];
|
|
|
|
forAllSystems = f: nixpkgs.lib.genAttrs systems (system: f nixpkgs.legacyPackages.${system});
|
|
mkZed =
|
|
pkgs:
|
|
let
|
|
rustBin = rust-overlay.lib.mkRustBin { } pkgs;
|
|
in
|
|
pkgs.callPackage ./nix/build.nix {
|
|
crane = crane.mkLib pkgs;
|
|
rustToolchain = rustBin.fromRustupToolchainFile ./rust-toolchain.toml;
|
|
};
|
|
in
|
|
{
|
|
packages = forAllSystems (pkgs: rec {
|
|
default = mkZed pkgs;
|
|
debug = default.override { profile = "dev"; };
|
|
});
|
|
devShells = forAllSystems (pkgs: {
|
|
default = pkgs.callPackage ./nix/shell.nix {
|
|
zed-editor = mkZed pkgs;
|
|
};
|
|
});
|
|
formatter = forAllSystems (pkgs: pkgs.nixfmt-rfc-style);
|
|
overlays.default = final: _: {
|
|
zed-editor = mkZed final;
|
|
};
|
|
};
|
|
|
|
nixConfig = {
|
|
extra-substituters = [
|
|
"https://zed.cachix.org"
|
|
"https://cache.garnix.io"
|
|
];
|
|
extra-trusted-public-keys = [
|
|
"zed.cachix.org-1:/pHQ6dpMsAZk2DiP4WCL0p9YDNKWj2Q5FL20bNmw1cU="
|
|
"cache.garnix.io:CTFPyKSLcx5RMJKfLo5EEPUObbA78b0YQ2DTCJXqr9g="
|
|
];
|
|
};
|
|
}
|